cloudmount/vendor/github.com/dropbox/dropbox-sdk-go-unofficial/generator/dropbox-api-spec/common.stone

namespace common

alias DropboxTimestamp = Timestamp("%Y-%m-%dT%H:%M:%SZ")

alias Date = Timestamp("%Y-%m-%d")

# Note - "\\." is needed in order to translate to "\."
alias EmailAddress = String(pattern="^['&A-Za-z0-9._%+-]+@[A-Za-z0-9-][A-Za-z0-9.-]*.[A-Za-z]{2,15}$", max_length=255)

# First name or Last name. NOTE: max_length should be synced with USER_NAME_MAX_LEN
alias NamePart = String(pattern="[^\/:?*<>\"|]*", min_length=1, max_length=100)

# Display name. We don't limit the length because it's always generated from the first & last names.
alias DisplayName = String(pattern="[^\/:?*<>\"|]*", min_length=1)

alias NamespaceId = String(pattern="[-_0-9a-zA-Z:]+")
alias SharedFolderId = NamespaceId

alias SessionId = String

alias PathRootId = NamespaceId

union PathRoot
    home
        "Paths are relative to the authenticating user's home directory,
        whether or not that user belongs to a team."

    member_home
        "Paths are relative to the authenticating team member's home
        directory. (This results in :field:`PathRootError.invalid' if the
        user does not belong to a team.)"

    team PathRootId
        "Paths are relative to the given team directory. (This results in
        :field:`PathRootError.invalid` if the user is not a member of
        the team associated with that path root id.)"

    user_home
        "Paths are relative to the user's home directory. (This results in
        :field:`PathRootError.invalid` if the belongs to a team.)"

    shared_folder PathRootId
        "Paths are relative to given shared folder id (This results in
        :field:`PathRootError.no_permission` if you don't have access
        to  this shared folder.)"


struct InvalidPathRootError
    path_root PathRootId?
        "The latest path root id for user's team if the user is still in
        a team."


union PathRootError
    invalid InvalidPathRootError
        "The path root id value in Dropbox-API-Path-Root header is no longer
        valid."
    no_permission
        "You don't have permission to access the path root id in Dropbox-API-Path-Root
         header."